First of all, you should not have thrown P-R 3.0* away. Secondly, the
rumor is that P-R 3.5 or at least 4.0 will have the #version returned so
3.0 files will be renderable as-is once again.
Anyway, here's my attempt at equalization of this halo using media, for
this example anyhow.

//BEGIN
 #declare Exhaust = intersection {
 box { <-2,0,-2>,<2,10,2>
 pigment { rgb 0 }
 }
     sphere { 0, 2
         pigment { color rgbf <1, 1, 1, 1> }
         interior {
          media { //as-is below this is 4X slower than halo
             emission <.4,.4,2> //half red&green? double blue? +??
             intervals 12 //lower grainy (3 equals speed of halo)
             samples 1,1 //higher slower if intervals is high too
    scattering {4,<2.4,2.4,.5> extinction .25} //3X and 1/2? type 4
           density {
             spherical
              density_map {  //see the emission and scattering vectors
                 [ 0 rgb <0,0,1> ] //same
                 [ 1 rgb <.8,.8,1>*1.5 ] //one and a half times original
             }
             scale 2.0
             turbulence sin(clock*2*pi)/4
         }
       }} //media&interior
         hollow
         scale <.3, 2, .1>
     } //sphere
 }
//END

Marc van den Dikkenberg wrote:
> 
> I recently upgraded to POV 3.1, after using POV 3.0 for a while.
> 
> This caused some problems with one of the objects I made, since 3.1
> apparently no longer supports Halo's... Unfortunately, I have no idea how
> to translate this code to 3.1.
> 
> (Hopefully this IS the right snippet, since I can't test-render it anymore.
>  It ought to be a blue/white exhaust flame for a vehicle I created)
> 
> Any help is appreciated!
> 
> //--------------------------------------------------------
> 
> #declare Exhaust = intersection {
> box { <-2,0,-2><2,10,2>
> pigment { Black }
> }
>     sphere { 0, 2
>         pigment { color rgbt <1, 1, 1, 1> }
>         halo {
>             emitting
>             spherical_mapping
>             linear
>             color_map {
>                 [ 0 color rgbt <0, 0, 1,  1> ]
>                 [ 1 color rgbt <.8, .8, 1, -1> ]
>             }
>             samples 10
>             scale 2.0
>             turbulence sin(clock*2*pi)/4
>         }
>         hollow
>         scale <.3, 2, .1>
>     }}
> 
> //--------------------------------------------------------
> --
> Marc van den Dikkenberg
> --
> The PowerBasic Archives -- http://www.xs4all.nl/~excel/pb.html
> All Basic Code Archives -- http://come.to/abcpackets

-- 
 omniVERSE: beyond the universe
  http://members.aol.com/inversez/POVring.htm
=Bob

Post a reply to this message